【v2】获取所有线程&中断线程

;==================================================
; Win10 V2 beta3
; 示例
;==================================================
Run(A_ScriptDir "\Hash.exe",,, &pid) ;; 打开进程
WinWait("ahk_pid " pid)
Sleep 1000
MsgBox threadId := GetProcessThread(pid)[1] ;; 取进程的第一个线程
MsgBox TerminateThread(threadId) ;; 中断线程, 成功返回1

;==================================================
; 返回包含指定进程的所有线程id的数组
;==================================================
GetProcessThread(pid) {
  threadEntry := Buffer(4 * 7), NumPut("uint", threadEntry.Size, threadEntry, 0)	;; initial
  if (-1 != threadSnapShot := DllCall("CreateToolhelp32Snapshot", "uint", 0x4, "uint", 0, "ptr")) {
    if (DllCall("Thread32First", "ptr", threadSnapShot, "ptr", threadEntry.Ptr, "int")) {
      arr := Array()
      loop {
        if (pid = NumGet(threadEntry, 12, "uint")) {
          arr.Push(NumGet(threadEntry, 8, "uint"))
        }
      } until !DllCall("Thread32Next", "ptr", threadSnapShot, "ptr", threadEntry.Ptr, "int")
    }
  }
  DllCall("CloseHandle", "ptr", threadSnapShot)
  return IsSet(arr) ? arr : 0
}

;==================================================
; 中断指定线程, 请谨慎使用
;==================================================
TerminateThread(threadId) {
  if (threadId := DllCall("OpenThread", "uint", 0x1f03ff, "int", 0, "uint", threadId, "ptr"))
    if (DllCall("GetExitCodeThread", "ptr", threadId, "uint*", &exitCode := 0))
      return DllCall("TerminateThread", "ptr", threadId, "uint", exitCode)
}

;==================================================
; 返回指定线程的入口地址
;==================================================
GetThreadAddress(threadId) {
  if (threadHandle := DllCall("OpenThread", "uint", 0x0040, "int", 0, "uint", threadId, "ptr"))
    return !DllCall("ntdll\NtQueryInformationThread", "ptr", threadHandle, "uint", 0x09, "ptr*", &Address := 0, "uint", A_PtrSize, "uint*", 0) ? Format("{:#X}", Address) : 0
}