AHK鼠标连击小工具

适用场景：

• 游戏玩家：用于快速触发鼠标点击动作（如射击、攻击等）。
• 日常操作：自动执行需要频繁点击的任务，减轻手动操作负担。
• 测试环境：自动化测试某些需要高频点击的功能。

扩展阅读：发送鼠标左键最快的写法

; 自己写的简单又能实现鼠标连击的小工具  By dbgba
#NoEnv
#NoTrayIcon
SetBatchLines -1
#SingleInstance Force
SetWorkingDir %A_ScriptDir%

Gui -MaximizeBox -MinimizeBox +AlwaysOnTop
Gui Add, Slider, w1 h1
Gui Add, Button, w120 g~LButton标签, 左键按住 连发
Gui Add, Button, w120 g~^LButton标签, Ctrl+左键 连发
Gui Add, Button, w120 gF4标签, F4开关 左键连发
Gui Show, , 鼠标连发工具
Return


~LButton标签:
~^LButton标签:
F4标签:
SetTimer 左键循环连击, Off
Hotkey, IfWinNotExist, ahk_pid 123456789
g标签的热键名 := StrReplace(A_ThisLabel, "标签")
标签分离变量 := Chr(StrLen(A_ThisLabel)+64)  ; 标签名长度转英文
if (%标签分离变量%onoff := !%标签分离变量%onoff) {
  Try Hotkey, % g标签的热键名, On
  Try Hotkey, % g标签的热键名 " Up", On
  Hotkey, % g标签的热键名, % (InStr(A_ThisLabel, "LButton") ? "左键连发按下标签" : "一键开关循环标签")
  Try Hotkey, % g标签的热键名 " Up", % (InStr(A_ThisLabel, "LButton") ? "左键连发松开标签" : "")
  Tip(g标签的热键名 " 热键已开启")
} else {
  Try Hotkey, % g标签的热键名, Off
  Try Hotkey, % g标签的热键名 " Up", Off
  Tip(g标签的热键名 " 热键已关闭")
}
Return

左键连发按下标签:
SetTimer 左键循环连击, 15
Return

左键连发松开标签:
SetTimer 左键循环连击, Off
Return


一键开关循环标签:
if (一键onoff := !一键onoff)
  SetTimer 左键循环连击, 15
 else
  SetTimer 左键循环连击, Off
Return

左键循环连击:
Send {LButton}
Return

GuiClose:
ExitApp


Tip(s:="", Period:="") {
  SetTimer %A_ThisFunc%, % s="" ? "Off" : "-" (Period="" ? 1500 : Period)
  ToolTip %s%, , , 17
}